VEGAS - Design Pattern d'inversion de contrôle : Définitions d'objets

import flash.text.TextField ;
import flash.text.TextFormat ;
 
import andromeda.ioc.core.ObjectDefinition ;
 
var init:Object =
{
    id         : "my_field" ,
    type       : "flash.text.TextField" ,
    singleton  : true ,
    properties :
    [
        { name : "defaultTextFormat" , value : new TextFormat("verdana", 11) } ,
        { name : "selectable"        , value : false                         } ,
        { name : "text"              , value : "hello world"                 }
    ]
}
 
var definition:ObjectDefinition = ObjectDefinition.create( init ) ;
 
trace( "definition.id              : " + definition.id ) ;
trace( "definition.getType()       : " + definition.getType() ) ;
trace( "definition.getScope()      : " + definition.getScope() ) ;
trace( "definition.isSingleton()   : " + definition.isSingleton() ) ;
trace( "definition.isLazyInit()    : " + definition.isLazyInit() ) ;
trace( "definition.getProperties() : " + definition.getProperties() )

package test
{
    import system.Reflection;
 
    /**
     * The User class.
     */
    public class User
    {
 
        /**
         * Creates a new User instance.
         */
        public function User( pseudo:String = null, name:String = null , address:Address = null )
        {
            this.pseudo  = pseudo ;
            this.name    = name ;
            this.address = address ;
        }
 
        /**
         * The Address reference of this object.
         */
        public var address:Address ;
 
        /**
         * The age of the user.
         */
        public var age:Number ;
 
        /**
         * The fistname of the user.
         */
        public var firstName:String ;
 
        /**
         * The job of this User.
         */
        public var job:Job ;
 
        /**
         * The mail of the user.
         */
        public var mail:String ;
 
        /**
         * The name of the User.
         */
        public var name:String ;
 
        /**
         * The pseudo of the user.
         */
        public var pseudo:String ;
 
        /**
         * The url of the User.
         */
        public var url:String ;
 
        /**
         * Destroy the user.
         */
        public function destroy():void
        {
            trace( this + " destroy.") ;
        }
 
        /**
         * Initialize the User.
         */
        public function initialize():void
        {
            trace( this + " initialize.") ;
        }
 
        /**
         * Sets the mail value of this user.
         */
        public function setMail( sMail:String ):void
        {
            mail = sMail ;
        }
 
        /**
         * Returns the string representation of the object.
         * @return the string representation of the object.
         */
        public override function toString():String
        {
            return "[" + Reflection.getClassName(this) + ( pseudo != null ? " " + pseudo : "" ) + "]" ;    
        }
    }
 
}

package test
{
 
    /**
     * The Address class
     */
    public class Address
    {
 
        /**
         * Creates a new Address instance.
         */
        public function Address( city:String = null , street:String = null , zip:Number = NaN )
        {
            this.city    = city ;
            this.street  = street ;
            this.zip     = zip    ;
        }
 
        /**
         * The city of this address.
         */
        public var city:String ;
 
        /**
         * The street of this address.
         */
        public var street:String ;
 
        /**
         * The zip code of this address.
         */
        public var zip:Number ;
 
    }
 
}
package test
{
    import system.Reflection;
 
    /**
     * The Job class.
     */
    public class Job
    {
 
        /**
         * Creates a new Job instance.
         */
        public function Job( name:String = null )
        {
            this.name = name ;
        }
 
        /**
         * The name of this Job.
         */
        public var name:String ;
 
        /**
         * Returns the string representation of this object.
         * @return the string representation of this object.
         */
        public override function toString():String
        {
            return "[" + Reflection.getClassName(this) + " " + name + "]" ;
        }
 
    }
 
}

objects =
[
    {  
        id            : "address"  ,
        type          : "test.Address" ,
        properties    :
        [
            { name : "city"   , value : "Marseille" } ,
            { name : "street" , value : "xx xxx xxxxxxxxxxx" } ,
            { name : "zip"    , value : 13001 }
        ]
    }
    ,
    {  
        id         : "job_dev"   ,
        type       : "test.Job"  ,
        scope      : "prototype" ,
        properties : [ { name:"name" , value:"AS Developper" } ]
    }   
    ,
    { 
        id         : "user" ,
        type       : "test.User" ,
        arguments    :
        [
            { value : "eKameleon" } ,
            { value : "ALCARAZ"   } ,
            { ref   : "address"   }
        ] ,
        lazyInit      : true ,
        singleton     : true ,
        destroy       : "destroy" ,
        init          : "initialize" ,
        properties    :
        [
             { name : "age"       , value : 31        } ,
             { name : "firstName" , value : "Marc"    } ,
             { name : "job"       , ref   : "job_dev" } ,
             { name : "url"       , value : "http://www.ekameleon.net" }
 
             { name : "setMail" , arguments : [ { value : "ekameleon [at] gmail.com" } ] }
        ]
    }
] ;

import andromeda.ioc.factory.ECMAObjectFactory ;
 
import test.User ;
 
 
var factory:ECMAObjectFactory = ECMAObjectFactory.getInstance() ;
 
factory.create( objects ) ;
 
var user:User = factory.getObject( "user" ) as User ;
 
trace( user ) ;